FeynRules initialization

Quit[]

$FeynRulesPath=SetDirectory["PATHTOFR/feynrules-current/"];
<<FeynRules`;
SetDirectory[NotebookDirectory[]<>"/FeynRules_source"];

((U(3))^5) flavor + (Subscript[m, W]) scheme

Flavor=U35;
Scheme=MwScheme;
LoadModel["SMEFTsim_main.fr"]

$Assumptions=assumptions;

Feynman rules for hVV vertices

Higgs vertices generated at 1 loop in the SM: implemented in (Subscript[m, t])->∞ limit

FeynmanRules[LSMloop,MaxParticles->3]//Simplify//TableForm

check a parameter definition

Select[M$Parameters,#[[1]]===gHgg4&]

CP even vertices hVV. Requires SM piece (LHiggs) + SMEFT corrections (class 4)

frHVV=FeynmanRules[LHiggs+LSMloop+L6cl4,MaxParticles->3,Contains->H];

frHVV//WCsimplify//TableForm

simplify the γγ one : relativeVariation gives (expr/SM)

frHVV[[2]]
%[[-1]]//relativeVariation//WCsimplify

the results are given in a scheme - independent format, as a function of the shift parameters.
  to convert to Wilson coefficients, use the replacement MwShifts

frHVV[[4]]
%[[-1]]//relativeVariation//WCsimplify
%//.MwShifts//WCsimplify

Feynman rules of Zff couplings

Z interactions to a fermion pair. SM piece is in LFermions, SMEFT corrections (no dipoles!) in class 7

frZfer=FeynmanRules[LFermions+L6cl7,Contains->{Z},MaxParticles->3]; (* takes a few minutes *)

frZfer//WCsimplify//TableForm

frZfer[[1]]//Simplify//WCsimplify
Zll=%[[-1]]//.MwShifts//WCsimplify

Isolate the contributions of cHl1 and cHl3 to Zll

Zll/.Alternatives@@{cll1,cHWB,cHe,cHDD}->0
(* right-handed*)
%/.TensDot[_,ProjM][_,_]->0//relativeVariation
(*left-handed*)
%%/.TensDot[_,ProjP][_,_]->0//relativeVariation//WCsimplify

Feynman rules of a given operator

bosonic operators can be called directly

OHB//FeynmanRules//Simplify//TableForm

Fermionic operators are defined with free flavor indices.

?OHl1

Safest option : isolate them by taking the Lagrangian part proportional to the corresponding Wilson coeff.

Select[L6cl7,!FreeQ[#,cHl1]&]//FeynmanRules//Simplify//TableForm

alternative : set to zero the coefficients of all operators except those we are interested in.

L6cl7/.Alternatives@@DeleteCases[WC6,cHl1|cHl3]->0//FeynmanRules[#,MaxParticles->3,Contains->{Z}]&//FullSimplify//TableForm

or : call for a given flavor combination (this ignores the flavor assumption)

OHl1[1,2]//Simplify

OHl1[1,1]//Simplify

((U(3))^5) flavor + α scheme

Flavor=U35;
Scheme=alphaScheme;
LoadModel["SMEFTsim_main.fr"]

$Assumptions=assumptions;

Feynman rules for hVV vertices

compute again HVV vertices to compare input scheme effects

frHVV=FeynmanRules[LHiggs+LSMloop+L6cl4,MaxParticles->3,Contains->H];

frHVV//WCsimplify//TableForm

frHVV[[2]]
%[[-1]]//relativeVariation//WCsimplify

frHVV[[4]]
%[[-1]]//relativeVariation//WCsimplify
%//.alphaShifts//WCsimplify

Feynman rules of Zff couplings

frZfer=FeynmanRules[LFermions+L6cl7,Contains->{Z},MaxParticles->3]; (* takes a few minutes *)

frZfer//WCsimplify//TableForm

frZfer[[1]]//Simplify//WCsimplify
%//.alphaShifts//WCsimplify

topU3l flavor + (Subscript[m, W]) scheme

Flavor=topU3l;
Scheme=MwScheme;
LoadModel["SMEFTsim_main.fr"];

$Assumptions=assumptions;

Feynman rules of Zff couplings

changing flavor : can be checked comparing Zff vertices

frZfer=FeynmanRules[LFermions+L6cl7,Contains->{Z},MaxParticles->3]; (* takes a few minutes *)

frZfer//WCsimplify//TableForm

in this case, (uq, dq) and (tq,bq) are independent fields.
The leptons sector is unchanged (it does change in the top models)

frZfer[[1]]//Simplify//WCsimplify
%//.MwShifts//WCsimplify